shader_type canvas_item;

// Перекраска части: заменяет ОТТЕНОК на целевой, подмешивает насыщенность,
// но СОХРАНЯЕТ яркость (запечённые тени/блики). Можно и осветлять через val_shift.
uniform bool enabled = false;
uniform vec4 target_color : source_color = vec4(1.0);
uniform float sat_mix : hint_range(0.0, 1.0) = 0.85;
uniform float val_shift : hint_range(-0.5, 0.5) = 0.0;

vec3 rgb2hsv(vec3 c) {
	vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
	vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
	vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));
	float d = q.x - min(q.w, q.y);
	float e = 1.0e-10;
	return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 hsv2rgb(vec3 c) {
	vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
	vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
	return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}

void fragment() {
	vec4 tex = texture(TEXTURE, UV);
	if (enabled && tex.a > 0.02) {
		vec3 hsv = rgb2hsv(tex.rgb);
		vec3 t = rgb2hsv(target_color.rgb);
		hsv.x = t.x;
		hsv.y = mix(hsv.y, t.y, sat_mix);
		hsv.z = clamp(hsv.z + val_shift, 0.0, 1.0);
		tex.rgb = hsv2rgb(hsv);
	}
	COLOR = tex * COLOR;
}